LFCRG

Computes the LU factorization of a real general matrix and estimates its L1 condition number.

Required Arguments

A — N by N matrix to be factored. (Input)

FACT — N by N matrix containing the LU factorization of the matrix A. (Output)
If A is not needed, A and FACT can share the same storage locations.

IPVT — Vector of length N containing the pivoting information for the LU factorization. (Output)

RCOND — Scalar containing an estimate of the reciprocal of the L1 condition number of A. (Output)

Optional Arguments

N — Order of the matrix. (Input)
Default: N = size (A,2).

LDA — Leading dimension of A exactly as specified in the dimension statement of the calling program. (Input)
Default: LDA = size (A,1).

LDFACT — Leading dimension of FACT exactly as specified in the dimension statement of the calling program. (Input)
Default: LDFACT = size (FACT,1).

FORTRAN 90 Interface

Generic: CALL LFCRG (A, FACT, IPVT, RCOND, [, …])

Specific: The specific interface names are S_LFCRG and D_LFCRG.

FORTRAN 77 Interface

Single: CALL LFCRG (N, A, LDA, FACT, LDFACT, IPVT, RCOND)

Double: The double precision name is DLFCRG.

ScaLAPACK Interface

Generic: CALL LFCRG (A0, FACT0, IPVT0, RCOND [, …])

Specific: The specific interface names are S_LFCRG and D_LFCRG.

See the ScaLAPACK Usage Notes below for a description of the arguments for distributed computing.

Description

Routine LFCRG performs an LU factorization of a real general coefficient matrix. It also estimates the condition number of the matrix. The underlying code is based on either LINPACK , LAPACK, or ScaLAPACK code depending upon which supporting libraries are used during linking. For a detailed explanation see Using ScaLAPACK, LAPACK, LINPACK, and EISPACK in the Introduction section of this manual. The LU factorization is done using scaled partial pivoting. Scaled partial pivoting differs from partial pivoting in that the pivoting strategy is the same as if each row were scaled to have the same ∞-norm. Otherwise, partial pivoting is used.

The L1 condition number of the matrix A is defined to be κ(A) = ∥A∥1∥A-1∥1. Since it is expensive to compute ∥A-1∥1, the condition number is only estimated. The estimation algorithm is the same as used by LINPACK and is described in a paper by Cline et al. (1979).

If the estimated condition number is greater than 1/ɛ (where ɛ is machine precision), a warning error is issued. This indicates that very small changes in A can cause very large changes in the solution x. Iterative refinement can sometimes find the solution to such a system.

LFCRG fails if U, the upper triangular part of the factorization, has a zero diagonal element. This can occur only if A either is singular or is very close to a singular matrix.

The LU factors are returned in a form that is compatible with functions LFIRG, LFSRG and LFDRG. To solve systems of equations with multiple right-hand-side vectors, use LFCRG followed by either LFIRG or LFSRG called once for each right-hand side. The routine LFDRG can be called to compute the determinant of the coefficient matrix after LFCRG has performed the factorization.

Let F be the matrix FACT and let p be the vector IPVT. The triangular matrix U is stored in the upper triangle of F. The strict lower triangle of F contains the information needed to reconstruct L using

L-1= LN-1PN-1 … L1P1

where Pk is the identity matrix with rows k and pk interchanged and Lk is the identity with Fik for i = k + 1, …, N inserted below the diagonal. The strict lower half of F can also be thought of as containing the negative of the multipliers. LFCRG is based on the LINPACK routine SGECO; see Dongarra et al. (1979). SGECO uses unscaled partial pivoting.

Comments

1. Workspace may be explicitly provided, if desired, by use of L2CRG/DL2CRG. The reference is:

CALL L2CRG (N, A, LDA, FACT, LDFACT, IPVT, RCOND, WK)

The additional argument is

WK — Work vector of length N.

2. Informational errors

Type	Code	Description
3	1	The input matrix is algorithmically singular.
4	2	The input matrix is singular.

ScaLAPACK Usage Notes

The arguments which differ from the standard version of this routine are:

A0 — MXLDA by MXCOL local matrix containing the local portions of the distributed matrix A. A contains the matrix to be factored. (Input)

FACT0 — MXLDA by MXCOL local matrix containing the local portions of the distributed matrix FACT. FACT contains the LU factorization of the matrix A. (Output)

IPVT0 — Local vector of length MXLDA containing the local portions of the distributed vector IPVT. IPVT contains the pivoting information for the LU factorization. (Output)

All other arguments are global and are the same as described for the standard version of the routine. In the argument descriptions above, MXLDA and MXCOL can be obtained through a call to SCALAPACK_GETDIM (see Utilities) after a call to SCALAPACK_SETUP (see Utilities) has been made. See the ScaLAPACK Example below.

Examples

Example 1

The inverse of a 3 × 3 matrix is computed. LFCRG is called to factor the matrix and to check for singularity or ill-conditioning. LFIRG is called to determine the columns of the inverse.

USE LFCRG_INT

USE UMACH_INT

USE LFIRG_INT

USE WRRRN_INT

! Declare variables

PARAMETER (LDA=3, LDFACT=3, N=3)

INTEGER IPVT(N), J, NOUT

REAL A(LDA,N), AINV(LDA,N), FACT(LDFACT,N), RCOND, &

RES(N), RJ(N)

! Set values for A

A(1,:) = (/ 1.0, 3.0, 3.0/)

A(2,:) = (/ 1.0, 3.0, 4.0/)

A(3,:) = (/ 1.0, 4.0, 3.0/)!

CALL LFCRG (A, FACT, IPVT, RCOND)

! Print the reciprocal condition number

! and the L1 condition number

CALL UMACH (2, NOUT)

WRITE (NOUT,99998) RCOND, 1.0E0/RCOND

! Set up the columns of the identity

! matrix one at a time in RJ

RJ = 0.0E0

DO 10 J=1, N

RJ(J) = 1.0

! RJ is the J-th column of the identity

! matrix so the following LFIRG

! reference places the J-th column of

! the inverse of A in the J-th column

! of AINV

CALL LFIRG (A, FACT, IPVT, RJ, AINV(:,J), RES)

RJ(J) = 0.0

10 CONTINUE

! Print results

CALL WRRRN (’AINV’, AINV)

99998 FORMAT (’ RCOND = ’,F5.3,/,’ L1 Condition number = ’,F6.3)

END

Output

RCOND < .02

L1 Condition number < 100.0

AINV

1 2 3

1 7.000 -3.000 -3.000

2 -1.000 0.000 1.000

3 -1.000 1.000 0.000

ScaLAPACK Example

The inverse of the same 3 × 3 matrix is computed as a distributed example. LFCRG is called to factor the matrix and to check for singularity or ill-conditioning. LFIRG is called to determine the columns of the inverse. SCALAPACK_MAP and SCALAPACK_UNMAP are IMSL utility routines (see Chapter 11, “Utilities”) used to map and unmap arrays to and from the processor grid. They are used here for brevity. DESCINIT is a ScaLAPACK tools routine which initializes the descriptors for the local arrays.

USE MPI_SETUP_INT

USE LFCRG_INT

USE UMACH_INT

USE LFIRG_INT

USE WRRRN_INT

USE SCALAPACK_SUPPORT

IMPLICIT NONE

INCLUDE ‘mpif.h’

! Declare variables

INTEGER J, LDA, N, DESCA(9), DESCL(9)

INTEGER INFO, MXCOL, MXLDA, NOUT

INTEGER, ALLOCATABLE :: IPVT0(:)

REAL, ALLOCATABLE :: A(:,:), AINV(:,:), X0(:), RJ(:)

REAL, ALLOCATABLE :: A0(:,:), FACT0(:,:), RES0(:), RJ0(:)

REAL RCOND

PARAMETER (LDA=3, N=3)

! Set up for MPI

MP_NPROCS = MP_SETUP()

IF(MP_RANK .EQ. 0) THEN

ALLOCATE (A(LDA,N), AINV(LDA,N))

! Set values for A

A(1,:) = (/ 1.0, 3.0, 3.0/)

A(2,:) = (/ 1.0, 3.0, 4.0/)

A(3,:) = (/ 1.0, 4.0, 3.0/)

ENDIF

! Set up a 1D processor grid and define

! its context id, MP_ICTXT

CALL SCALAPACK_SETUP(N, N, .TRUE., .TRUE.)

! Get the array descriptor entities MXLDA,

! and MXCOL

CALL SCALAPACK_GETDIM(N, N, MP_MB, MP_NB, MXLDA, MXCOL)

! Set up the array descriptors

CALL DESCINIT(DESCA, N, N, MP_MB, MP_NB, 0, 0, MP_ICTXT, MXLDA, INFO)

CALL DESCINIT(DESCL, N, 1, MP_MB, 1, 0, 0, MP_ICTXT, MXLDA, INFO)

! Allocate space for the local arrays

ALLOCATE(A0(MXLDA,MXCOL), X0(MXLDA),FACT0(MXLDA,MXCOL), RJ(N), &

RJ0(MXLDA), RES0(MXLDA), IPVT0(MXLDA))

! Map input arrays to the processor grid

CALL SCALAPACK_MAP(A, DESCA, A0)

! Call the factorization routine

CALL LFCRG (A0, FACT0, IPVT0, RCOND)

! Print the reciprocal condition number

! and the L1 condition number

IF(MP_RANK .EQ. 0) THEN

CALL UMACH (2, NOUT)

WRITE (NOUT,99998) RCOND, 1.0E0/RCOND

ENDIF

! Set up the columns of the identity

! matrix one at a time in RJ

RJ = 0.0E0

DO 10 J=1, N

RJ(J) = 1.0

CALL SCALAPACK_MAP(RJ, DESCL, RJ0)

! RJ is the J-th column of the identity

! matrix so the following LFIRG

! reference computes the J-th column of

! the inverse of A

CALL LFIRG (A0, FACT0, IPVT0, RJ0, X0, RES0)

RJ(J) = 0.0

CALL SCALAPACK_UNMAP(X0, DESCL, AINV(:,J))

10 CONTINUE

! Print results

! Only Rank=0 has the solution, X.

IF(MP_RANK.EQ.0) CALL WRRRN (’AINV’, AINV)

IF (MP_RANK .EQ. 0) DEALLOCATE(A, AINV)

DEALLOCATE(A0, IPVT0, FACT0, RES0, RJ, RJ0, X0)

! Exit ScaLAPACK usage

CALL SCALAPACK_EXIT(MP_ICTXT)

! Shut down MPI

MP_NPROCS = MP_SETUP(‘FINAL’)