Solves a complex triangular system of linear equations.

Required Arguments

A — Complex N by N matrix containing the coefficient matrix of the triangular linear system.   (Input)
For a lower triangular system, only the lower triangle of A is referenced. For an upper triangular system, only the upper triangle of A is referenced.

B — Complex vector of length N containing the right-hand side of the linear system.   (Input)

X — Complex vector of length N containing the solution to the linear system.   (Output)
If B is not needed, B and X can share the same storage locations.

Optional Arguments

N — Number of equations.   (Input)
Default: N = size (A,2).

LDA — Leading dimension of A exactly as specified in the dimension statement of the calling program.   (Input)
Default: LDA = size (A,1).

IPATH — Path indicator.   (Input)
IPATH = 1 means solve AX = B, A lower triangular
IPATH = 2 means solve AX = B, A upper triangular
IPATH = 3 means solve AHX = B, A lower triangular
IPATH = 4 means solve AHX = B, A upper triangular
Default: IPATH = 1.

FORTRAN 90 Interface

Generic:                              CALL LSLCT (A, B, X [,…])

Specific:                             The specific interface names are S_LSLCT and D_LSLCT.

FORTRAN 77 Interface

Single:                                CALL LSLCT (N, A, LDA, B, IPATH, X)

Double:                              The double precision name is DLSLCT.

ScaLAPACK Interface

Generic:                              CALL LSLCT (A0, B0, X0 [,…])

Specific:                             The specific interface names are S_LSLCT and D_LSLCT.

See the ScaLAPACK Usage Notes below for a description of the arguments for distributed computing.

Description

Routine LSLCT solves a system of linear algebraic equations with a complex triangular coefficient matrix. LSLCT fails if the matrix A has a zero diagonal element, in which case A is singular. The underlying code is based on either LINPACK , LAPACK, or ScaLAPACK code depending upon which supporting libraries are used during linking. For a detailed explanation see “Using ScaLAPACK, LAPACK, LINPACK, and EISPACK” in the Introduction section of this manual.

Comments

Informational error

Type       Code

4                   1          The input triangular matrix is singular. Some of its diagonal elements are near zero.

ScaLAPACK Usage Notes

The arguments which differ from the standard version of this routine are:

A0 —   MXLDA by MXCOL complex local matrix containing the local portions of the distributed matrix A.  A contains the coefficient matrix of the triangular linear system.   (Input)
For a lower triangular system, only the lower triangular part and diagonal of A are referenced. For an upper triangular system, only the upper triangular part and diagonal of A are referenced.

B0 —   Local complex vector of length MXLDA containing the local portions of the distributed vector B. B contains the right-hand side of the linear system.   (Input)

X0 —   Local complex vector  of length MXLDA containing the local portions of the distributed vector X. X  contains the solution to the linear system.   (Output)
If B is not needed, B and X can share the same storage locations.

All other arguments are global and are the same as described for the standard version of the routine. In the argument descriptions above,  MXLDA and MXCOL can be obtained through a call to SCALAPACK_GETDIM (see Utilities) after a call to  SCALAPACK_SETUP (see Utilities) has been made. See the ScaLAPACK Example below.

Example

A system of three linear equations is solved. The coefficient matrix has lower triangular form and the right-hand-side vector, b, has three elements.

 

      USE LSLCT_INT
      USE WRCRN_INT

!                                 Declare variables

      INTEGER      LDA

      PARAMETER    (LDA=3)

      COMPLEX      A(LDA,LDA), B(LDA), X(LDA)

!                                Set values for A and B

!

!                                A = ( -3.0+2.0i                     )

!                                    ( -2.0-1.0i  0.0+6.0i           )

!                                    ( -1.0+3.0i  1.0-5.0i -4.0+0.0i )

!

!                                B = (-13.0+0.0i -10.0-1.0i -11.0+3.0i)

!

      DATA A/(-3.0,2.0), (-2.0,-1.0), (-1.0, 3.0), (0.0,0.0), (0.0,6.0),&

            (1.0,-5.0), (0.0,0.0), (0.0,0.0), (-4.0,0.0)/

      DATA B/(-13.0,0.0), (-10.0,-1.0), (-11.0,3.0)/

!

!                                 Solve AX = B

      CALL LSLCT (A, B, X)

!                                 Print results

      CALL WRCRN ('X', X, 1, 3, 1)

      END

Output

 

                           X
              1                2                3
( 3.000, 2.000)  ( 1.000, 1.000)  ( 2.000, 0.000)

ScaLAPACK Example

The same lower triangular matrix as in the example above is used in this distributed computing example. The system of three linear equations is solved. SCALAPACK_MAP and SCALAPACK_UNMAP are IMSL utility routines (see Chapter 11, “Utilities”) used to map and unmap arrays to and from the processor grid. They are used here for brevity. DESCINIT is a ScaLAPACK tools routine which initializes the descriptors for the local arrays.

 

      USE MPI_SETUP_INT
      USE LSLCT_INT

      USE WRCRN_INT
      USE SCALAPACK_SUPPORT

      IMPLICIT NONE

      INCLUDE ‘mpif.h'

!                                 Declare variables

      INTEGER        LDA, N, DESCA(9), DESCX(9)
      INTEGER       INFO, MXCOL, MXLDA
      COMPLEX, ALLOCATABLE ::        A(:,:), B(:), X(:)
      COMPLEX, ALLOCATABLE ::        A0(:,:), B0(:), X0(:)

      PARAMETER      (LDA=3, N=3)

!                                 Set up for MPI

      MP_NPROCS = MP_SETUP()
      IF(MP_RANK .EQ. 0) THEN
          ALLOCATE (A(LDA,N), B(N), X(N))

!                                 Set values for A

          A(1,:) = (/ (-3.0,  2.0), (0.0,  0.0), ( 0.0, 0.0)/)
          A(2,:) = (/ (-2.0, -1.0), (0.0,  6.0), ( 0.0, 0.0)/)
          A(3,:) = (/ (-1.0,  3.0), (1.0, -5.0), (-4.0, 0.0)/)

!        

          B      = (/ (-13.0, 0.0), (-10.0, -1.0), (-11.0, 3.0)
      ENDIF

!                                  Set up a 1D processor grid and define

!                                  its context ID, MP_ICTXT

      CALL SCALAPACK_SETUP(N, N, .TRUE., .TRUE.)

!                                  Get the array descriptor entities MXLDA,

!                                  and MXCOL

      CALL SCALAPACK_GETDIM(N, N, MP_MB, MP_NB, MXLDA, MXCOL)

!                                  Set up the array descriptor

      CALL DESCINIT(DESCA, N, N, MP_MB, MP_NB, 0, 0, MP_ICTXT, MXLDA, INFO)

      CALL DESCINIT(DESCX, N, 1, MP_MB, 1, 0, 0, MP_ICTXT, MXLDA, INFO)
!                                   Allocate space for the local arrays

      ALLOCATE (A0(MXLDA,MXCOL), B0(MXLDA), X0(MXLDA))

!                                 Map input arrays to the processor grid

      CALL SCALAPACK_MAP(A, DESCA, A0)

      CALL SCALAPACK_MAP(B, DESCX, B0)

!                                 Solve AX = B

      CALL LSLCT (A0, B0, X0)

!                                 Unmap the results from the distributed

!                                 arrays back to a non-distributed array.

!                                 After the unmap, only Rank=0 has the full

!                                 array.

      CALL SCALAPACK_UNMAP(X0, DESCX, X)

!                                 Print results.

!                                 Only Rank=0 has the solution, X.

      IF(MP_RANK .EQ. 0) CALL WRCRN (‘X', X, 1, 3, 1)

      IF (MP_RANK .EQ. 0) DEALLOCATE(A, B, X)

      DEALLOCATE(A0, B0, X0)

!                                 Exit ScaLAPACK usage

      CALL SCALAPACK_EXIT(MP_ICTXT)

!                                 Shut down MPI

      MP_NPROCS = MP_SETUP(‘FINAL')
      END

Output

 

                           X
              1                2                3
( 3.000, 2.000)  ( 1.000, 1.000)  ( 2.000, 0.000)

Visual Numerics, Inc. Visual Numerics - Developers of IMSL and PV-WAVE http://www.vni.com/ PHONE: 713.784.3131 FAX:713.781.9260